Attachment 48921 Details for Bug 115410

menu file, from previous installed system from pegasos board

menu (text/plain), 1.94 KB, created by Patrick Kirsch on 2005-09-06 13:19:25 UTC

(hide)

Description:

Filename:

MIME Type:

Creator: Patrick Kirsch

Created: 2005-09-06 13:19:25 UTC

Size: 1.94 KB

patch

obsolete

>\ FORTH is identifed by a forth comment at first line
>\
>\ terminal control stuff
>\
>: TTY.CSI d# 27 EMIT ASCII [ EMIT ;
>: TTY.HOME    TTY.CSI ASCII H EMIT ;
>: TTY.CLR_EOS TTY.CSI ASCII J EMIT ;
>: TTY.HOME_CLR TTY.HOME TTY.CLR_EOS ;
>\
>\ boot menu stuff
>\
>: my-max-boot-num 5 ;
>: my-boot-default 5 ;
>: my-boot-delay d# 300 ; \ unit = 100 ms
>: my-print-menu ( -- )
>  TTY.HOME_CLR
>  ."  "							cr
>  ." Pegasos Boot Menu"					cr
>  ."  "							cr
>  ." 1: Debian GNU/Linux 3.1 (Sarge)"			cr
>  ." 2: Ubuntu (Hoary)"					cr
>  ." 3: Gentoo (2005.0)"				cr
>  ." 4: return to OF prompt"				cr
>  ." 5: suse"				cr
>  ."  "							cr
>;
>: my-boot-case ( num -- )
>  ."  " cr
>  case
>    1 of " hd:2 boot/vmlinuz-2.6.11-powerpc root=/dev/hda3"		endof
>    2 of " hd:3 boot/vmlinuz-2.6.10-5-powerpc root=/dev/hda4"		endof
>    3 of " hd:4 boot/gentoo root=/dev/hda5"				endof
>    4 of " none" endof
>    5 of " hd:0 test root=/dev/hdd8"				endof
>  endcase
>  $boot
>;
>: my-input-num ( wait-period max-boot-num default-num -- boot-num )
>  1 \ loop-inc = 1
>  3 pick 0 do
>    0d emit
>    ." press 1-"
>    ( wait-period max-boot-num default-num loop-inc )
>    2 pick ascii 0 + emit
>    dup 1 = if
>      ."  within "
>      3 pick i - d# 10 / .d
>      ."  seconds"
>    then
>    ."  (default: "
>    over ascii 0 + emit
>    ." ) :                   "
>    d# 100 ms
>    key? if
>       key
>       ( wait-period max-boot-num default-num loop-inc key )
>       dup 0d = if \ return pressed
>         drop leave
>       then
>
>       ascii 0 -
>       ( wait-period max-boot-num default-num loop-inc num )
>       dup 1 5 pick
>       ( wait-period max-boot-num default-num loop-inc num num 1 max-boot-num )
>       between if
>         rot drop swap leave
>       then
>
>       ( wait-period max-boot-num default-num loop-inc num )
>       2drop 0  \ loop-inc = 0
>    then
>  dup +loop
>  drop
>  ( wait-period max-boot-num boot-num )
>  nip nip
>;
>
>
>my-print-menu
>my-boot-delay my-max-boot-num my-boot-default my-input-num
>my-boot-case

Actions: View

Attachments on bug 115410: 48921